miniblink事件的绑定其实也比较简单，例如：

wke.事件_标题被改变 (&子程序1)


.子程序 子程序1
.参数 参数_webView, 整数型
.参数 参数_用户数据, 整数型
.参数 参数_title, 整数型, , wkeString

_启动窗口.标题 ＝ WKE取文本 (参数_title)
输出调试文本 (wke.取标题 ())

但要注意的是：事件绑定必须要在 wke.绑定（） 后面，只有当mb先绑定了窗口，才能绑定事件，事件的回调子程序参数在下方有模板可以参考；当然，你直接套用也可以，这就是mb事件绑定的全部内容了。

miniblink 事件可以直接套用下面模板：

.版本 2


' 事件绑定需要在 wke.绑定（）后面
wke.事件_标题被改变 (&wke_标题被改变)
wke.事件_Alert被调用 (&wke_Alert被调用)
wke.事件_Confirm被调用 (&wke_Confirm被调用)
wke.事件_Prompt被调用 (&wke_Prompt被调用)
wke.事件_控制台消息 (&wke_控制台消息)
wke.事件_即将导航 (&wke_即将导航)
wke.事件_文档就绪2 (&wke_文档就绪2)
wke.事件_载入完成 (&wke_载入完成)
wke.事件_即将创建新窗口 (&web_事件_即将创建新窗口)
wke.事件_脚本上下文创建 (&wke_事件_脚本上下文创建)
' wke.事件_开始载入URL (&wke_事件_开始载入URL)
' wke.事件_网络响应 (&wke_事件_网络响应)
' wke.事件_鼠标经过URL改变 (&wke_事件_鼠标经过URL被改变)



.子程序 wke_标题被改变
.参数 参数_webView, 整数型
.参数 参数_用户数据, 整数型
.参数 参数_title, 整数型, , wkeString

_启动窗口.标题 ＝ WKE取文本 (参数_title)

输出调试文本 (wke.取标题 ())

.子程序 wke_Alert被调用
.参数 参数_webView, 整数型
.参数 参数_用户数据, 整数型
.参数 参数_消息, 整数型

信息框 (WKE取文本 (参数_消息), 0, )

.子程序 wke_Confirm被调用, 逻辑型
.参数 参数_webView, 整数型
.参数 参数_用户数据, 整数型
.参数 参数_消息, 整数型

返回 (信息框 (WKE取文本 (参数_消息), #是否钮, ) ＝ #是钮)


.子程序 wke_Prompt被调用, 逻辑型
.参数 参数_webView, 整数型
.参数 参数_用户数据, 整数型
.参数 参数_提示信息, 整数型
.参数 参数_默认值, 整数型
.参数 参数_返回值, 整数型
.局部变量 ret, 文本型

.如果真 (输入框 (WKE取文本 (参数_提示信息), , WKE取文本 (参数_默认值), ret, ))
    WKE置文本 (参数_返回值, ret)
    返回 (真)
.如果真结束
返回 (假)


.子程序 wke_即将导航, 逻辑型
.参数 参数_webView, 整数型
.参数 参数_用户数据, 整数型
.参数 参数_类型, 整数型, , “WKE导航类型_”开头常量
.参数 参数_URL, 整数型

调试输出 (“即将导航：”, 参数_类型, WKE取文本 (参数_URL))
返回 (真)

.子程序 wke_控制台消息
.参数 webView, 整数型
.参数 参数_用户数据, 整数型
.参数 级别, 整数型, , “WKE消息级别_”开头常量
.参数 消息, 整数型, , wkeString
.参数 源名称, 整数型, , wkeString
.参数 行号, 整数型
.参数 堆栈跟踪, 整数型, , wkeString

调试输出 (“控制台消息：”, 级别, WKE取文本 (消息), WKE取文本 (源名称), 行号, WKE取文本 (堆栈跟踪))

.子程序 wke_文档就绪2
.参数 参数_webView, 整数型
.参数 参数_用户数据, 整数型
.参数 参数_框架句柄, 整数型
.局部变量 v, 长整数型

调试输出 (“文档就绪2”, 参数_框架句柄)
' v ＝ wke.运行JS自框架 (参数_框架句柄, “document.getElementsByTagName('html')[0].outerHTML;”, )
' 输出调试文本 (JS到文本 (wke.全局执行 (), v))


.子程序 wke_载入完成
.参数 参数_webView, 整数型
.参数 参数_用户数据, 整数型
.参数 url, 整数型
.参数 参数_载入结果, 整数型, , “WKE载入_”开头常量
.参数 参数_失败原因, 整数型

调试输出 (“载入完成：”, WKE取文本 (url), 参数_载入结果, WKE取文本 (参数_失败原因))



.子程序 web_事件_即将创建新窗口, 整数型
.参数 webView, 整数型
.参数 lParam, 整数型
.参数 导航类型, 整数型, , “WKE导航类型_”开头常量
.参数 url, 整数型, , wkeString
.参数 窗口特征, 整数型

调试输出 (“即将创建新窗口：”, 到文本 (导航类型), WKE取文本 (url))

返回 (wke.取浏览器指针 ())  ' 这里不能返回自己

.子程序 wke_事件_脚本上下文创建
.参数 webView, 整数型
.参数 lParam, 整数型
.参数 frame, 整数型
.参数 context, 整数型
.参数 extensionGroup, 整数型
.参数 worldId, 整数型

调试输出 (“脚本上下文创建”, frame, context, extensionGroup, worldId)

.子程序 wke_事件_网络响应, 逻辑型
.参数 webView, 整数型
.参数 lParam, 整数型
.参数 url, 文本型
.参数 job, 整数型

调试输出 (“网络响应”, url, WKE网络取MIMEType (job))
返回 (假)

例程&源码下载

下载链接：https://www.huib.top/archives/1734880798955